comin_callback.F90

Go to the documentation of this file.

!> @file comin_callback.F90
!! @brief Routines to handle third party plugin callbacks.
!
!  @authors 08/2021 :: ICON Community Interface  <comin@icon-model.org>
!
!  SPDX-License-Identifier: BSD-3-Clause
!
!  See LICENSES for license information.
!  Where software is supplied by third parties, it is indicated in the
!  headers of the routines.
!
MODULE comin_callback
 
  USE iso_c_binding, ONLY: c_int, c_funptr, c_funloc, c_bool, c_ptr
  USE comin_c_utils,              ONLY: convert_c_string
 
  IMPLICIT NONE
 
  PRIVATE
 
  PUBLIC :: comin_callback_routine
  PUBLIC :: comin_callback_register
  PUBLIC :: comin_callback_get_ep_name
  PUBLIC :: comin_callback_context_call
 
#include "comin_global.inc"
 
  abstract INTERFACE
    SUBROUTINE comin_callback_routine() BIND(C)
    END SUBROUTINE comin_callback_routine
  END INTERFACE
 
  INTERFACE
    SUBROUTINE comin_callback_register_f(entry_point_id, comin_callback_fct) BIND(C)
      IMPORT c_int, c_funptr
      INTEGER(c_int), VALUE, INTENT(IN) :: entry_point_id
      TYPE(c_funptr), VALUE, INTENT(IN) :: comin_callback_fct
    END SUBROUTINE comin_callback_register_f
 
    SUBROUTINE comin_callback_context_call(entry_point_id, domain_id, lacc) BIND(C)
      IMPORT c_int, c_bool
      INTEGER(KIND=C_INT), INTENT(IN), VALUE  :: entry_point_id
      INTEGER(KIND=C_INT), INTENT(IN), VALUE  :: domain_id
      LOGICAL(KIND=C_BOOL), INTENT(IN), VALUE :: lacc
    END SUBROUTINE comin_callback_context_call
 
    FUNCTION comin_callback_get_ep_name_c(entry_point_id) &
         & result(ep_name) &
         & BIND(C, name="comin_callback_get_ep_name")
      IMPORT c_int, c_ptr
      INTEGER(KIND=C_INT), INTENT(IN), VALUE  :: entry_point_id
      TYPE(c_ptr) :: ep_name
    END FUNCTION comin_callback_get_ep_name_c
  END INTERFACE
 
CONTAINS
 
  !> Routine to register new callbacks during primary constructor.
  !! @ingroup fortran_interface
  SUBROUTINE comin_callback_register(entry_point_id, comin_callback_fct)
    INTEGER, INTENT(IN) :: entry_point_id
    PROCEDURE(comin_callback_routine) :: comin_callback_fct
 
    CALL comin_callback_register_f(entry_point_id, c_funloc(comin_callback_fct))
  END SUBROUTINE comin_callback_register
 
  !> returns entry point name (character string) corresponding to `iep`.
  !! @ingroup fortran_interface
  SUBROUTINE comin_callback_get_ep_name( iep, out_ep_name )
    INTEGER, INTENT(IN)  :: iep   !< entry point ID
    CHARACTER(LEN=:), ALLOCATABLE, INTENT(OUT) :: out_ep_name !< entry point name string
 
    out_ep_name = convert_c_string(comin_callback_get_ep_name_c(iep))
  END SUBROUTINE comin_callback_get_ep_name
 
END MODULE comin_callback