comin_state.F90

Go to the documentation of this file.

 
!
!  @authors 10/2023 :: ICON Community Interface  <comin@icon-model.org>
!
!  SPDX-License-Identifier: BSD-3-Clause
!
!  See LICENSES for license information.
!  Where software is supplied by third parties, it is indicated in the
!  headers of the routines.
!
MODULE comin_state
 
  USE iso_c_binding,         ONLY:  c_int, c_ptr
  USE comin_setup_constants, ONLY:  domain_undefined, wp
  USE comin_plugin_types,    ONLY:  t_comin_plugin_info
  USE comin_parallel_types,  ONLY:  t_comin_parallel_info
  USE comin_callback_types,  ONLY:  t_comin_callback_context
  USE comin_descrdata_types, ONLY:  t_comin_descrdata_global,       &
    &                               t_comin_descrdata_domain,       &
    &                               t_comin_descrdata_simulation_interval, &
    &                               comin_glb2loc_index_lookup_fct
  USE comin_variable_types,  ONLY:  t_comin_var_list_context,       &
    &                               comin_var_sync_device_mem_fct,  &
    &                               comin_var_sync_halo_fct
  USE comin_errhandler_constants, ONLY: comin_success
  USE comin_errhandler_types, ONLY: comin_host_errhandler_fct
 
  PRIVATE
  PUBLIC :: comin_setup_set_verbosity_level
  PUBLIC :: comin_setup_get_verbosity_level
  PUBLIC :: comin_current_get_ep
  PUBLIC :: comin_current_get_domain_id
 
#include "comin_global.inc"
 
  TYPE, PUBLIC :: t_comin_state
 
    ! current error state of comin
    INTEGER :: errcode = comin_success
 
    ! verbosity level, related to ICON's `msg_level`.
    ! 0 = silent
    INTEGER :: comin_iverbosity = 0
 
    LOGICAL :: lstdout = .true.
    INTEGER :: output_unit = 0
 
    ! number of 3rd party plugins associated
    INTEGER :: num_plugins      = 0
 
    ! plugin infos
    TYPE(t_comin_plugin_info), ALLOCATABLE :: plugin_info(:)
 
    ! currently active 3rd party plugin
    TYPE(t_comin_plugin_info), POINTER :: current_plugin
 
    ! (Non-public) data structure
    TYPE(t_comin_parallel_info) :: parallel_info
 
    TYPE(c_ptr)                                 :: comin_callback_list
    TYPE(t_comin_callback_context), ALLOCATABLE :: comin_callback_context(:,:)
    INTEGER, ALLOCATABLE                        :: comin_callback_order(:,:)
 
    TYPE(t_comin_descrdata_global)                 :: comin_descrdata_global
    TYPE(t_comin_descrdata_domain), ALLOCATABLE    :: comin_descrdata_domain(:)
    TYPE(t_comin_descrdata_simulation_interval)    :: comin_descrdata_simulation_interval
    REAL(wp), ALLOCATABLE                          :: comin_descrdata_timesteplength(:)
 
    TYPE(c_ptr) :: comin_var_descr_list
    TYPE(c_ptr) :: comin_var_list
 
    TYPE(t_comin_var_list_context), ALLOCATABLE :: comin_var_list_context(:,:)
 
    TYPE(c_ptr) :: comin_var_request_list
 
    ! translates global cell indices to process-local indices
    procedure(comin_glb2loc_index_lookup_fct), POINTER, NOPASS :: comin_descrdata_fct_glb2loc_cell
 
    ! Global variable which contains the callback to ICON's "finish"
    ! routine.
    PROCEDURE(comin_host_errhandler_fct), POINTER, NOPASS :: comin_host_finish => null()
 
    ! current simulation date-time stamp (ISO 8601)
    CHARACTER(LEN=COMIN_MAX_DATETIME_STR_LEN) :: current_datetime
 
    INTEGER  :: current_domain_id   = domain_undefined
    INTEGER  :: current_ep
 
    LOGICAL  :: l_primary_done = .false.
 
    procedure(comin_var_sync_device_mem_fct), POINTER, NOPASS :: sync_device_mem
 
    procedure(comin_var_sync_halo_fct), POINTER, NOPASS :: sync_halo
 
  END TYPE t_comin_state
 
  TYPE(t_comin_state), PUBLIC, POINTER :: state => null()
 
CONTAINS
 
  SUBROUTINE comin_setup_set_verbosity_level(iverbosity)
    INTEGER, INTENT(IN)   :: iverbosity
 
    state%comin_iverbosity = iverbosity
  END SUBROUTINE comin_setup_set_verbosity_level
 
  FUNCTION comin_setup_get_verbosity_level()
    INTEGER :: comin_setup_get_verbosity_level
    comin_setup_get_verbosity_level = state%comin_iverbosity
  END FUNCTION comin_setup_get_verbosity_level
 
  FUNCTION comin_current_get_ep()  BIND(C)
    INTEGER(c_int) :: comin_current_get_ep
    comin_current_get_ep = int(state%current_ep, c_int)
  END FUNCTION comin_current_get_ep
 
  FUNCTION comin_current_get_domain_id()  &
    &  BIND(C)
    INTEGER(c_int) :: comin_current_get_domain_id
 
    comin_current_get_domain_id = -1
    IF (state%current_domain_id /= domain_undefined) THEN
      comin_current_get_domain_id = int(state%current_domain_id, c_int)
    END IF
  END FUNCTION comin_current_get_domain_id
 
END MODULE comin_state