comin_metadata.F90

Go to the documentation of this file.

!> @file comin_metadata.F90
!! @brief Variable metadata definition.
!
!  @authors 11/2023 :: ICON Community Interface  <comin@icon-model.org>
!
!  SPDX-License-Identifier: BSD-3-Clause
!
!  See LICENSES for license information.
!  Where software is supplied by third parties, it is indicated in the
!  headers of the routines.
!
MODULE comin_metadata
 
  USE iso_c_binding,           ONLY: c_int, c_ptr, c_bool, c_double, c_char, c_loc, c_associated
  USE comin_setup_constants,   ONLY: wp,                              &
   &                                 comin_metadata_typeid_undefined, &
   &                                 comin_metadata_typeid_integer, &
   &                                 comin_metadata_typeid_real, &
   &                                 comin_metadata_typeid_character, &
   &                                 comin_metadata_typeid_logical
  USE comin_errhandler_types,  ONLY: comin_error_metadata_set_outside_primaryconstructor, &
    &                                comin_error_var_descriptor_not_found,                &
    &                                comin_error_tracer_request_not_for_all_domains,      &
    &                                comin_error_var_metadata_inconsistent_type
  USE comin_errhandler,        ONLY: comin_error_set
  USE comin_state,             ONLY: state, comin_state_is_primary_done
  USE comin_c_utils,           ONLY: convert_c_string
  USE comin_variable_types,    ONLY: t_comin_var_descriptor,                              &
    &                                t_comin_var_descriptor_c
  USE comin_var_request,       ONLY: comin_var_request_find_c, comin_var_request_get_metadata
  USE comin_metadata_types,    ONLY: t_comin_var_metadata, t_comin_var_metadata_iterator
  USE comin_c_utils,           ONLY: convert_f_string
 
  IMPLICIT NONE
 
  PRIVATE
 
  PUBLIC :: comin_metadata_set
  PUBLIC :: comin_metadata_set_host
  PUBLIC :: comin_metadata_get
  PUBLIC :: comin_metadata_get_or
  PUBLIC :: comin_metadata_get_typeid
  PUBLIC :: comin_metadata_get_iterator
  PUBLIC :: comin_metadata_set_integer_c, comin_metadata_set_real_c
  PUBLIC :: comin_metadata_set_character_c, comin_metadata_set_logical_c
 
#include "comin_global.inc"
 
  !> Sets metadata for a requested ComIn variable.
  !> **Note:Plugins use the alias `comin_metadata_set`.**
  !! @ingroup fortran_interface
  INTERFACE comin_metadata_set
    MODULE PROCEDURE comin_request_set_var_metadata_logical
    MODULE PROCEDURE comin_request_set_var_metadata_integer
    MODULE PROCEDURE comin_request_set_var_metadata_real
    MODULE PROCEDURE comin_request_set_var_metadata_character
  END INTERFACE comin_metadata_set
 
  !> Sets metadata for an exposed variable.
  !> **Note: The host model uses the alias `comin_metadata_set`.**
  INTERFACE comin_metadata_set_host
    MODULE PROCEDURE comin_metadata_host_set_logical
    MODULE PROCEDURE comin_metadata_host_set_integer
    MODULE PROCEDURE comin_metadata_host_set_real
    MODULE PROCEDURE comin_metadata_host_set_character
  END INTERFACE comin_metadata_set_host
 
  !> Read-only access to additional information about a given variable.
  !! @ingroup fortran_interface
  INTERFACE comin_metadata_get
    MODULE PROCEDURE comin_metadata_get_logical
    MODULE PROCEDURE comin_metadata_get_integer
    MODULE PROCEDURE comin_metadata_get_real
    MODULE PROCEDURE comin_metadata_get_character
  END INTERFACE comin_metadata_get
 
  INTERFACE comin_metadata_get_or
    MODULE PROCEDURE comin_metadata_get_or_integer
    MODULE PROCEDURE comin_metadata_get_or_real
    MODULE PROCEDURE comin_metadata_get_or_character
    MODULE PROCEDURE comin_metadata_get_or_logical
  END INTERFACE comin_metadata_get_or
 
  INTERFACE
    SUBROUTINE comin_metadata_host_set_int_c(descriptor, key, val) &
         & BIND(C, name="comin_metadata_host_set_int")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_int
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      INTEGER(C_INT), VALUE,                 INTENT(IN)  :: val !< metadata value
    END SUBROUTINE comin_metadata_host_set_int_c
 
    SUBROUTINE comin_metadata_host_set_bool_c(descriptor, key, val) &
         & BIND(C, name="comin_metadata_host_set_bool")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_bool
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      LOGICAL(C_BOOL), VALUE,                 INTENT(IN) :: val !< metadata value
    END SUBROUTINE comin_metadata_host_set_bool_c
 
    SUBROUTINE comin_metadata_host_set_double_c(descriptor, key, val) &
         & BIND(C, name="comin_metadata_host_set_double")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_double
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      REAL(C_DOUBLE), VALUE,                 INTENT(IN)  :: val !< metadata value
    END SUBROUTINE comin_metadata_host_set_double_c
 
    SUBROUTINE comin_metadata_host_set_string_c(descriptor, key, val) &
         & BIND(C, name="comin_metadata_host_set_string")
      IMPORT t_comin_var_descriptor_c, c_ptr
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: val !< metadata value
    END SUBROUTINE comin_metadata_host_set_string_c
 
    FUNCTION comin_metadata_get_int_c(descriptor, key) RESULT(val) &
      BIND(C, name="comin_metadata_get_int")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_int
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      INTEGER(C_INT)                                     :: val !< metadata value
    END FUNCTION comin_metadata_get_int_c
 
    FUNCTION comin_metadata_get_bool_c(descriptor, key) RESULT(val) &
      BIND(C, name="comin_metadata_get_bool")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_int, c_bool
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      LOGICAL(C_BOOL)                                    :: val !< metadata value
    END FUNCTION comin_metadata_get_bool_c
 
    FUNCTION comin_metadata_get_double_c(descriptor, key) RESULT(val) &
      BIND(C, name="comin_metadata_get_double")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_int, c_double
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      REAL(C_DOUBLE)                                     :: val !< metadata value
    END FUNCTION comin_metadata_get_double_c
 
    FUNCTION comin_metadata_get_string_c(descriptor, key) RESULT(val) &
      BIND(C, name="comin_metadata_get_string")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_int
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      TYPE(C_PTR)                                        :: val !< metadata value
    END FUNCTION comin_metadata_get_string_c
 
    FUNCTION comin_metadata_get_typeid_c(descriptor, key) RESULT(typeid) &
      BIND(C, name="comin_metadata_get_typeid")
      IMPORT t_comin_var_descriptor_c, c_ptr, c_int
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR), VALUE,                    INTENT(IN)  :: key !< metadata key (name)
      INTEGER(C_INT)                                     :: typeid
    END FUNCTION comin_metadata_get_typeid_c
 
    FUNCTION comin_metadata_get_iterator_begin(descriptor) RESULT(begin) &
         & BIND(C)
      IMPORT t_comin_var_descriptor_c, c_ptr
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR) :: begin
    END FUNCTION comin_metadata_get_iterator_begin
 
    FUNCTION comin_metadata_get_iterator_end(descriptor) RESULT(end_) &
         & BIND(C)
      IMPORT t_comin_var_descriptor_c, c_ptr
      TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: descriptor !< variable descriptor
      TYPE(C_PTR) :: end_
    END FUNCTION comin_metadata_get_iterator_end
  END INTERFACE
 
CONTAINS
 
  !> Set metadata for item in variable list.
  SUBROUTINE comin_metadata_host_set_integer(descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    INTEGER,                      INTENT(IN)  :: val !< metadata value
    !
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = descriptor%id
    CALL convert_f_string(descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
    CALL comin_metadata_host_set_int_c(descriptor_c, c_loc(key_c), val)
  END SUBROUTINE comin_metadata_host_set_integer
 
  !> Set metadata for item in variable list.
  SUBROUTINE comin_metadata_host_set_logical(descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    LOGICAL,                      INTENT(IN)  :: val !< metadata value
    !
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = descriptor%id
    CALL convert_f_string(descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
    CALL comin_metadata_host_set_bool_c(descriptor_c, c_loc(key_c), LOGICAL(val, C_BOOL))
  END SUBROUTINE comin_metadata_host_set_logical
 
  !> Set metadata for item in variable list.
  SUBROUTINE comin_metadata_host_set_real(descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    REAL(wp),                     INTENT(IN)  :: val !< metadata value
    !
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = descriptor%id
    CALL convert_f_string(descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
    CALL comin_metadata_host_set_double_c(descriptor_c, c_loc(key_c), val)
  END SUBROUTINE comin_metadata_host_set_real
 
  !> Set metadata for item in variable list.
  SUBROUTINE comin_metadata_host_set_character(descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    CHARACTER(LEN=*),             INTENT(IN)  :: val !< metadata value
    !
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: val_c(:)
 
    descriptor_c%id = descriptor%id
    CALL convert_f_string(descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
    ALLOCATE(val_c(len_trim(val)+1))
    CALL convert_f_string(val, val_c)
    CALL comin_metadata_host_set_string_c(descriptor_c, c_loc(key_c), c_loc(val_c))
  END SUBROUTINE comin_metadata_host_set_character
 
  !> request the metadata to a variable
  SUBROUTINE comin_metadata_get_integer(var_descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    INTEGER,                      INTENT(OUT) :: val !< metadata value
    ! local
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = var_descriptor%id
    CALL convert_f_string(var_descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
 
    val = comin_metadata_get_int_c(descriptor_c, c_loc(key_c))
  END SUBROUTINE comin_metadata_get_integer
 
  !> request the metadata to a variable
  SUBROUTINE comin_metadata_get_logical(var_descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    LOGICAL,                      INTENT(OUT) :: val !< metadata value
    ! local
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = var_descriptor%id
    CALL convert_f_string(var_descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
 
    val = comin_metadata_get_bool_c(descriptor_c, c_loc(key_c))
  END SUBROUTINE comin_metadata_get_logical
 
  !> request the metadata to a variable
  SUBROUTINE comin_metadata_get_real(var_descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    REAL(wp),                     INTENT(OUT) :: val !< metadata value
    ! local
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = var_descriptor%id
    CALL convert_f_string(var_descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
 
    val = comin_metadata_get_double_c(descriptor_c, c_loc(key_c))
  END SUBROUTINE comin_metadata_get_real
 
  !> request the metadata to a variable
  SUBROUTINE comin_metadata_get_character(var_descriptor, key, val)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    CHARACTER(LEN=:), ALLOCATABLE,INTENT(OUT) :: val !< metadata value
    ! local
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
    TYPE(c_ptr) :: val_c
 
    descriptor_c%id = var_descriptor%id
    CALL convert_f_string(var_descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
 
    val_c = comin_metadata_get_string_c(descriptor_c, c_loc(key_c))
    val = convert_c_string(val_c)
  END SUBROUTINE comin_metadata_get_character
 
  SUBROUTINE comin_metadata_get_or_integer(metadata, key, val, defaultval)
    TYPE(t_comin_var_metadata), INTENT(inout) :: metadata
    CHARACTER(LEN=*), INTENT(in) :: key
    INTEGER, INTENT(out) :: val
    INTEGER, INTENT(in) :: defaultval
 
    SELECT CASE ( metadata%query(key) )
    CASE (comin_metadata_typeid_integer)
      CALL metadata%get(key, val)
    CASE (comin_metadata_typeid_undefined)
      val = defaultval
    CASE DEFAULT
      CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
    END SELECT
  END SUBROUTINE comin_metadata_get_or_integer
 
  SUBROUTINE comin_metadata_get_or_real(metadata, key, val, defaultval)
    TYPE(t_comin_var_metadata), INTENT(inout) :: metadata
    CHARACTER(LEN=*), INTENT(in) :: key
    REAL(wp), INTENT(out) :: val
    REAL(wp), INTENT(in) :: defaultval
 
    SELECT CASE ( metadata%query(key) )
    CASE (comin_metadata_typeid_real)
      CALL metadata%get(key, val)
    CASE (comin_metadata_typeid_undefined)
      val = defaultval
    CASE DEFAULT
      CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
    END SELECT
  END SUBROUTINE comin_metadata_get_or_real
 
  SUBROUTINE comin_metadata_get_or_character(metadata, key, val, defaultval)
    TYPE(t_comin_var_metadata), INTENT(inout) :: metadata
    CHARACTER(LEN=*), INTENT(in) :: key
    CHARACTER(LEN=:), ALLOCATABLE, INTENT(out) :: val
    CHARACTER(LEN=*), INTENT(in) :: defaultval
 
    SELECT CASE ( metadata%query(key) )
    CASE (comin_metadata_typeid_character)
      CALL metadata%get(key, val)
    CASE (comin_metadata_typeid_undefined)
      val = defaultval
    CASE DEFAULT
      CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
    END SELECT
  END SUBROUTINE comin_metadata_get_or_character
 
  SUBROUTINE comin_metadata_get_or_logical(metadata, key, val, defaultval)
    TYPE(t_comin_var_metadata), INTENT(inout) :: metadata
    CHARACTER(LEN=*), INTENT(in) :: key
    LOGICAL, INTENT(out) :: val
    LOGICAL, INTENT(in) :: defaultval
 
    SELECT CASE ( metadata%query(key) )
    CASE (comin_metadata_typeid_logical)
      CALL metadata%get(key, val)
    CASE (comin_metadata_typeid_undefined)
      val = defaultval
    CASE DEFAULT
      CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
    END SELECT
  END SUBROUTINE comin_metadata_get_or_logical
 
  SUBROUTINE comin_metadata_set_integer_c(var_descriptor, key, val) &
    &  BIND(C, name="comin_metadata_set_integer")
    TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: var_descriptor !< variable descriptor
    TYPE(c_ptr), VALUE,             INTENT(IN)  :: key !< metadata key (name)
    INTEGER(kind=c_int), VALUE,     INTENT(IN)  :: val !< metadata value
    !
    TYPE (t_comin_var_descriptor) :: var_descriptor_fortran
 
    var_descriptor_fortran = t_comin_var_descriptor(var_descriptor)
    CALL comin_request_set_var_metadata_integer(var_descriptor_fortran, &
      &                                         convert_c_string(key), val)
  END SUBROUTINE comin_metadata_set_integer_c
 
  SUBROUTINE comin_metadata_set_logical_c(var_descriptor, key, val) &
    &  BIND(C, name="comin_metadata_set_logical")
    TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: var_descriptor !< variable descriptor
    TYPE(c_ptr), VALUE,             INTENT(IN)  :: key !< metadata key (name)
    LOGICAL(C_BOOL), VALUE,         INTENT(IN)  :: val !< metadata value
    !
    TYPE (t_comin_var_descriptor) :: var_descriptor_fortran
 
    var_descriptor_fortran = t_comin_var_descriptor(var_descriptor)
    CALL comin_request_set_var_metadata_logical(var_descriptor_fortran, &
      &                                         convert_c_string(key), LOGICAL(val))
  END SUBROUTINE comin_metadata_set_logical_c
 
  SUBROUTINE comin_metadata_set_real_c(var_descriptor, key, val) &
    &  BIND(C, name="comin_metadata_set_real")
    TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: var_descriptor !< variable descriptor
    TYPE(c_ptr), VALUE,             INTENT(IN)  :: key !< metadata key (name)
    REAL(wp), VALUE,                INTENT(IN)  :: val !< metadata value
    !
    TYPE (t_comin_var_descriptor) :: var_descriptor_fortran
 
    var_descriptor_fortran = t_comin_var_descriptor(var_descriptor)
    CALL comin_request_set_var_metadata_real(var_descriptor_fortran, &
      &                                      convert_c_string(key), real(val, wp))
  END SUBROUTINE comin_metadata_set_real_c
 
  SUBROUTINE comin_metadata_set_character_c(var_descriptor, key, val) &
    &  BIND(C, name="comin_metadata_set_character")
    TYPE(t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: var_descriptor !< variable descriptor
    TYPE(c_ptr), VALUE,             INTENT(IN)  :: key !< metadata key (name)
    TYPE(c_ptr), VALUE,             INTENT(IN)  :: val !< metadata value
    !
    TYPE (t_comin_var_descriptor) :: var_descriptor_fortran
 
    var_descriptor_fortran = t_comin_var_descriptor(var_descriptor)
    CALL comin_request_set_var_metadata_character(var_descriptor_fortran, &
      &                                           convert_c_string(key), convert_c_string(val))
  END SUBROUTINE comin_metadata_set_character_c
 
  !> Sets a specific metadata item (represented by a key-value pair)
  !  for a requested variable. Must be called inside the primary
  !  constructor and the variable must have been previously requested,
  !  otherwise this subroutine aborts with an error status flag.  If
  !  the metadata key does not exist, then this subroutine aborts with
  !  an error status flag.
  !
  SUBROUTINE comin_request_set_var_metadata_integer(var_descriptor, key, val)
    TYPE (t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),              INTENT(IN)  :: key !< metadata key (name)
    INTEGER,                       INTENT(IN)  :: val !< metadata value
    ! local
    INTEGER :: domain_id, domain_id_start, domain_id_end
    LOGICAL :: lfound
    TYPE(t_comin_var_descriptor_c) :: var_descriptor_domain
    TYPE(c_ptr) :: req
    TYPE(t_comin_var_metadata) :: metadata
 
    ! check if called in primary constructor
    IF (comin_state_is_primary_done()) THEN
      CALL comin_error_set(comin_error_metadata_set_outside_primaryconstructor); RETURN
    END IF
 
    IF (var_descriptor%id == -1) THEN
      domain_id_start = 1
      domain_id_end   = state%comin_descrdata_global_data%n_dom
    ELSE
      domain_id_start = var_descriptor%id
      domain_id_end   = var_descriptor%id
    END IF
 
    var_descriptor_domain = t_comin_var_descriptor_c(var_descriptor)
 
    ! loop over request list
    lfound = .false.
    DO domain_id = domain_id_start, domain_id_end
      var_descriptor_domain%id = domain_id
 
      req = comin_var_request_find_c(var_descriptor_domain)
 
      IF (c_associated(req)) THEN
        lfound = .true.
        metadata = comin_var_request_get_metadata(req)
 
        IF (all(metadata%query(trim(key)) /= &
          &     [ comin_metadata_typeid_undefined, comin_metadata_typeid_integer ])) THEN
          CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
        ENDIF
        CALL metadata%set(key, val)
      END IF
    END DO
 
    IF (.NOT. lfound) THEN
      CALL comin_error_set(comin_error_var_descriptor_not_found); RETURN
    ENDIF
  END SUBROUTINE comin_request_set_var_metadata_integer
 
  !> Sets a specific metadata item (represented by a key-value pair)
  !  for a requested variable. Must be called inside the primary
  !  constructor and the variable must have been previously requested,
  !  otherwise this subroutine aborts with an error status flag.  If
  !  the metadata key does not exist, then this subroutine aborts with
  !  an error status flag.
  !
  SUBROUTINE comin_request_set_var_metadata_logical(var_descriptor, key, val)
    TYPE (t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),              INTENT(IN)  :: key !< metadata key (name)
    LOGICAL,                       INTENT(IN)  :: val !< metadata value
    ! local
    INTEGER :: domain_id, domain_id_start, domain_id_end
    LOGICAL :: lfound
    TYPE(t_comin_var_descriptor_c) :: var_descriptor_domain
    TYPE(c_ptr) :: req
    TYPE(t_comin_var_metadata) :: metadata
 
    ! check if called in primary constructor
    IF (comin_state_is_primary_done()) THEN
      CALL comin_error_set(comin_error_metadata_set_outside_primaryconstructor); RETURN
    END IF
 
    IF (var_descriptor%id == -1) THEN
      domain_id_start = 1
      domain_id_end   = state%comin_descrdata_global_data%n_dom
    ELSE
      IF ((key == "tracer") .AND. val) THEN
        CALL comin_error_set(comin_error_tracer_request_not_for_all_domains); RETURN
      END IF
 
      domain_id_start = var_descriptor%id
      domain_id_end   = var_descriptor%id
    END IF
 
    var_descriptor_domain = t_comin_var_descriptor_c(var_descriptor)
 
    ! loop over request list
    lfound = .false.
    DO domain_id = domain_id_start, domain_id_end
      var_descriptor_domain%id = domain_id
 
      req = comin_var_request_find_c(var_descriptor_domain)
 
      IF (c_associated(req)) THEN
        lfound = .true.
        metadata = comin_var_request_get_metadata(req)
 
        IF (all(metadata%query(trim(key)) /= &
          &     [ comin_metadata_typeid_undefined, comin_metadata_typeid_logical ])) THEN
          CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
        ENDIF
        CALL metadata%set(key, val)
      END IF
    END DO
 
    IF (.NOT. lfound)  THEN
      CALL comin_error_set(comin_error_var_descriptor_not_found); RETURN
    ENDIF
  END SUBROUTINE comin_request_set_var_metadata_logical
 
  !> Sets a specific metadata item (represented by a key-value pair)
  !  for a requested variable. Must be called inside the primary
  !  constructor and the variable must have been previously requested,
  !  otherwise this subroutine aborts with an error status flag.  If
  !  the metadata key does not exist, then this subroutine aborts with
  !  an error status flag.
  !
  SUBROUTINE comin_request_set_var_metadata_real(var_descriptor, key, val)
    TYPE (t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),              INTENT(IN)  :: key !< metadata key (name)
    REAL(wp),                      INTENT(IN)  :: val !< metadata value
    ! local
    INTEGER :: domain_id, domain_id_start, domain_id_end
    LOGICAL :: lfound
    TYPE(t_comin_var_descriptor_c) :: var_descriptor_domain
    TYPE(c_ptr) :: req
    TYPE(t_comin_var_metadata) :: metadata
 
    ! check if called in primary constructor
    IF (comin_state_is_primary_done()) THEN
      CALL comin_error_set(comin_error_metadata_set_outside_primaryconstructor); RETURN
    END IF
 
    IF (var_descriptor%id == -1) THEN
      domain_id_start = 1
      domain_id_end   = state%comin_descrdata_global_data%n_dom
    ELSE
      domain_id_start = var_descriptor%id
      domain_id_end   = var_descriptor%id
    END IF
 
    var_descriptor_domain = t_comin_var_descriptor_c(var_descriptor)
 
    ! loop over request list
    lfound = .false.
    DO domain_id = domain_id_start, domain_id_end
      var_descriptor_domain%id = domain_id
 
      req = comin_var_request_find_c(var_descriptor_domain)
 
      IF (c_associated(req)) THEN
        lfound = .true.
        metadata = comin_var_request_get_metadata(req)
 
        IF (all(metadata%query(trim(key)) /= &
          &     [ comin_metadata_typeid_undefined, comin_metadata_typeid_real ])) THEN
          CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
        ENDIF
        CALL metadata%set(key, val)
      END IF
    END DO
 
    IF (.NOT. lfound) THEN
      CALL comin_error_set(comin_error_var_descriptor_not_found); RETURN
    ENDIF
  END SUBROUTINE comin_request_set_var_metadata_real
 
  !> Sets a specific metadata item (represented by a key-value pair)
  !  for a requested variable. Must be called inside the primary
  !  constructor and the variable must have been previously requested,
  !  otherwise this subroutine aborts with an error status flag.  If
  !  the metadata key does not exist, then this subroutine aborts with
  !  an error status flag.
  !
  SUBROUTINE comin_request_set_var_metadata_character(var_descriptor, key, val)
    TYPE (t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),              INTENT(IN)  :: key !< metadata key (name)
    CHARACTER(LEN=*),              INTENT(IN)  :: val !< metadata value
    ! local
    INTEGER :: domain_id, domain_id_start, domain_id_end
    LOGICAL :: lfound
    TYPE(t_comin_var_descriptor_c) :: var_descriptor_domain
    TYPE(c_ptr) :: req
    TYPE(t_comin_var_metadata) :: metadata
 
    ! check if called in primary constructor
    IF (comin_state_is_primary_done()) THEN
      CALL comin_error_set(comin_error_metadata_set_outside_primaryconstructor); RETURN
    END IF
 
    IF (var_descriptor%id == -1) THEN
      domain_id_start = 1
      domain_id_end   = state%comin_descrdata_global_data%n_dom
    ELSE
      domain_id_start = var_descriptor%id
      domain_id_end   = var_descriptor%id
    END IF
 
    var_descriptor_domain = t_comin_var_descriptor_c(var_descriptor)
 
    ! loop over request list
    lfound = .false.
    DO domain_id = domain_id_start, domain_id_end
      var_descriptor_domain%id = domain_id
 
      req = comin_var_request_find_c(var_descriptor_domain)
 
      IF (c_associated(req)) THEN
        lfound = .true.
        metadata = comin_var_request_get_metadata(req)
 
        IF (all(metadata%query(trim(key)) /= &
          &     [ comin_metadata_typeid_undefined, comin_metadata_typeid_character ])) THEN
          CALL comin_error_set(comin_error_var_metadata_inconsistent_type); RETURN
        ENDIF
        CALL metadata%set(key, val)
      END IF
    END DO
 
    IF (.NOT. lfound) THEN
      CALL comin_error_set(comin_error_var_descriptor_not_found); RETURN
    ENDIF
  END SUBROUTINE comin_request_set_var_metadata_character
 
  !> Return a ID (integer) describing the metadata data type of a metadata.
  !! @ingroup fortran_interface
  INTEGER FUNCTION comin_metadata_get_typeid(var_descriptor, key)  RESULT(typeid)
    TYPE(t_comin_var_descriptor), INTENT(IN)  :: var_descriptor !< variable descriptor
    CHARACTER(LEN=*),             INTENT(IN)  :: key !< metadata key (name)
    ! local
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    CHARACTER(len=1, kind=c_char), ALLOCATABLE, TARGET :: key_c(:)
 
    descriptor_c%id = var_descriptor%id
    CALL convert_f_string(var_descriptor%name, descriptor_c%name)
    ALLOCATE(key_c(len_trim(key)+1))
    CALL convert_f_string(key, key_c)
 
    typeid = comin_metadata_get_typeid_c(descriptor_c, c_loc(key_c))
  END FUNCTION comin_metadata_get_typeid
 
  !> Return a metadata container iterator
  !! @ingroup fortran_interface
  SUBROUTINE comin_metadata_get_iterator(var_descriptor, iterator)
    TYPE(t_comin_var_descriptor), INTENT(IN)         :: var_descriptor
    TYPE(t_comin_var_metadata_iterator), INTENT(OUT) :: iterator
    ! local
    TYPE(t_comin_var_descriptor_c)  :: descriptor_c !< variable descriptor
    descriptor_c%id = var_descriptor%id
    CALL convert_f_string(var_descriptor%name, descriptor_c%name)
 
    iterator%comin_metadata_iterator_current_c = comin_metadata_get_iterator_begin(descriptor_c)
    iterator%comin_metadata_iterator_end_c = comin_metadata_get_iterator_end(descriptor_c)
  END SUBROUTINE comin_metadata_get_iterator
 
END MODULE comin_metadata