comin_metadata_types.F90

Go to the documentation of this file.

 
!
!  @authors 08/2024 :: ICON Community Interface  <comin@icon-model.org>
!
!  SPDX-License-Identifier: BSD-3-Clause
!
!  See LICENSES for license information.
!  Where software is supplied by third parties, it is indicated in the
!  headers of the routines.
!
MODULE comin_metadata_types
 
  USE iso_c_binding,         ONLY: c_int, c_char, c_double, c_bool, &
                               &   c_ptr, c_loc, c_null_ptr, c_associated
  USE comin_c_utils,         ONLY: convert_c_string, convert_f_string
  USE comin_keyval_ifc,      ONLY: comin_keyval_create_c, comin_keyval_delete_c, &
                               &   comin_keyval_get_bool_c, comin_keyval_get_char_c, &
                               &   comin_keyval_get_double_c, comin_keyval_get_int_c, &
                               &   comin_keyval_iterator_begin_c, comin_keyval_iterator_compare_c, &
                               &   comin_keyval_iterator_delete_c, comin_keyval_iterator_end_c, &
                               &   comin_keyval_iterator_get_key_c, comin_keyval_iterator_next_c, &
                               &   comin_keyval_query_c, comin_keyval_set_bool_c, &
                               &   comin_keyval_set_char_c, comin_keyval_set_double_c, &
                               &   comin_keyval_set_int_c
 
  PRIVATE
 
  PUBLIC :: t_comin_var_metadata, t_comin_var_metadata_iterator
 
#include "comin_global.inc"
 
  TYPE t_comin_var_metadata_iterator
    TYPE(c_ptr) :: comin_metadata_iterator_current_c = c_null_ptr
    TYPE(c_ptr) :: comin_metadata_iterator_end_c     = c_null_ptr
  CONTAINS
    PROCEDURE :: next    => comin_metadata_iterator_next
    PROCEDURE :: is_end  => comin_metadata_iterator_is_end
    PROCEDURE :: key     => comin_metadata_get_key_from_iterator
    PROCEDURE :: delete  => comin_metadata_iterator_delete
  END TYPE t_comin_var_metadata_iterator
 
  TYPE t_comin_var_metadata
    TYPE(c_ptr) :: comin_metadata_c = c_null_ptr
  CONTAINS
    PROCEDURE :: create              => comin_metadata_create
    PROCEDURE :: delete              => comin_metadata_delete
    PROCEDURE :: query               => comin_metadata_query
    PROCEDURE :: get_iterator        => comin_metadata_get_iterator
    generic, PUBLIC    :: set        => set_int, set_double, set_char, set_bool
    PROCEDURE, PRIVATE :: set_int    => comin_metadata_set_int
    PROCEDURE, PRIVATE :: set_double => comin_metadata_set_double
    PROCEDURE, PRIVATE :: set_char   => comin_metadata_set_char
    PROCEDURE, PRIVATE :: set_bool   => comin_metadata_set_bool
    generic, PUBLIC    :: get        => get_int, get_double, get_char, get_bool
    PROCEDURE, PRIVATE :: get_int    => comin_metadata_get_int
    PROCEDURE, PRIVATE :: get_double => comin_metadata_get_double
    PROCEDURE, PRIVATE :: get_char   => comin_metadata_get_char
    PROCEDURE, PRIVATE :: get_bool   => comin_metadata_get_bool
  END TYPE t_comin_var_metadata
 
CONTAINS
 
  SUBROUTINE comin_metadata_create(this)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    ! If metadata container is already created, simply ignore this step
    ! (entries can be still be added/modified via set in that case)
    IF ( .NOT. c_associated(this%comin_metadata_c) ) THEN
      CALL comin_keyval_create_c(this%comin_metadata_c)
    ENDIF
  END SUBROUTINE comin_metadata_create
 
  SUBROUTINE comin_metadata_delete(this)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CALL comin_keyval_delete_c(this%comin_metadata_c)
  END SUBROUTINE comin_metadata_delete
 
  INTEGER FUNCTION comin_metadata_query(this, key)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    INTEGER(KIND=c_int) :: idx
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_query_c(c_loc(ckey), idx, this%comin_metadata_c)
 
    comin_metadata_query = int(idx)
  END FUNCTION comin_metadata_query
 
  SUBROUTINE comin_metadata_set_int(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    INTEGER(KIND=c_int), INTENT(in)  :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_set_int_c(c_loc(ckey), val, this%comin_metadata_c)
 
  END SUBROUTINE comin_metadata_set_int
 
  SUBROUTINE comin_metadata_get_int(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    INTEGER(KIND=c_int), INTENT(out)  :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_get_int_c(c_loc(ckey), val, this%comin_metadata_c)
  END SUBROUTINE comin_metadata_get_int
 
  SUBROUTINE comin_metadata_set_double(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    REAL(KIND=c_double), INTENT(in)  :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_set_double_c(c_loc(ckey), val, this%comin_metadata_c)
 
  END SUBROUTINE comin_metadata_set_double
 
  SUBROUTINE comin_metadata_get_double(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    REAL(KIND=c_double), INTENT(out)  :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_get_double_c(c_loc(ckey), val, this%comin_metadata_c)
  END SUBROUTINE comin_metadata_get_double
 
  SUBROUTINE comin_metadata_set_char(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key, val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1), cval(LEN(TRIM(val))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL convert_f_string(trim(val), cval)
    CALL comin_keyval_set_char_c(c_loc(ckey), c_loc(cval), this%comin_metadata_c)
 
  END SUBROUTINE comin_metadata_set_char
 
  SUBROUTINE comin_metadata_get_char(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    CHARACTER(LEN=:), ALLOCATABLE, INTENT(out) :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
    TYPE(c_ptr) :: cval
 
    cval = c_null_ptr
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_get_char_c(c_loc(ckey), cval, this%comin_metadata_c)
    val = convert_c_string(cval)
  END SUBROUTINE comin_metadata_get_char
 
  SUBROUTINE comin_metadata_set_bool(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    LOGICAL, INTENT(in) :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_set_bool_c(c_loc(ckey), LOGICAL(val,c_bool), this%comin_metadata_c)
 
  END SUBROUTINE comin_metadata_set_bool
 
  SUBROUTINE comin_metadata_get_bool(this, key, val)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    CHARACTER(LEN=*), INTENT(in) :: key
    LOGICAL, INTENT(out)  :: val
    CHARACTER(len=1, KIND=c_char), TARGET :: ckey(LEN(TRIM(key))+1)
    LOGICAL(KIND=c_bool) :: cval
 
    CALL convert_f_string(trim(key), ckey)
    CALL comin_keyval_get_bool_c(c_loc(ckey), cval, this%comin_metadata_c)
    val = LOGICAL(cval)
  END SUBROUTINE comin_metadata_get_bool
 
  SUBROUTINE comin_metadata_get_iterator(this, iterator)
    CLASS(t_comin_var_metadata), INTENT(inout) :: this
    TYPE(t_comin_var_metadata_iterator), INTENT(inout) :: iterator
 
    IF (c_associated(iterator%comin_metadata_iterator_current_c)) CALL iterator%delete()
    CALL comin_keyval_iterator_begin_c(this%comin_metadata_c, iterator%comin_metadata_iterator_current_c)
    CALL comin_keyval_iterator_end_c  (this%comin_metadata_c, iterator%comin_metadata_iterator_end_c    )
  END SUBROUTINE comin_metadata_get_iterator
 
  FUNCTION comin_metadata_get_key_from_iterator(this) RESULT(key)
    CLASS(t_comin_var_metadata_iterator), INTENT(in) :: this
    CHARACTER(LEN=:), ALLOCATABLE :: key
    TYPE(c_ptr) :: ckey
 
    ckey = comin_keyval_iterator_get_key_c(this%comin_metadata_iterator_current_c)
    key = convert_c_string(ckey)
  END FUNCTION comin_metadata_get_key_from_iterator
 
  SUBROUTINE comin_metadata_iterator_next(this)
    CLASS(t_comin_var_metadata_iterator), INTENT(in) :: this
 
    CALL comin_keyval_iterator_next_c(this%comin_metadata_iterator_current_c)
  END SUBROUTINE comin_metadata_iterator_next
 
  SUBROUTINE comin_metadata_iterator_delete(this)
    CLASS(t_comin_var_metadata_iterator), INTENT(inout) :: this
 
    CALL comin_keyval_iterator_delete_c(this%comin_metadata_iterator_current_c)
    CALL comin_keyval_iterator_delete_c(this%comin_metadata_iterator_end_c    )
    this%comin_metadata_iterator_current_c = c_null_ptr ! Reset c_ptr such that c_associated can be used
    this%comin_metadata_iterator_end_c     = c_null_ptr ! Reset c_ptr such that c_associated can be used
  END SUBROUTINE
 
  LOGICAL FUNCTION comin_metadata_iterator_is_end(this)
    CLASS(t_comin_var_metadata_iterator), INTENT(inout) :: this
 
    comin_metadata_iterator_is_end = LOGICAL(comin_keyval_iterator_compare_c( &
      &  this%comin_metadata_iterator_current_c, this%comin_metadata_iterator_end_c) )
  END FUNCTION comin_metadata_iterator_is_end
 
END MODULE comin_metadata_types