comin_var_request.F90

Go to the documentation of this file.

!> @file comin_variable.F90
!! @brief Functions to modify and retrieve Variable definition
!!
!! @authors 08/2021 :: ICON Community Interface  <comin@icon-model.org>
!!
!! SPDX-License-Identifier: BSD-3-Clause
!!
!! See LICENSES for license information.
!! Where software is supplied by third parties, it is indicated in the
!! headers of the routines.
!!
 
MODULE comin_var_request
 
  use, INTRINSIC :: iso_c_binding, only: c_bool, c_ptr, c_f_pointer
  USE comin_variable_types, ONLY: t_comin_var_descriptor, t_comin_var_descriptor_c
  USE comin_metadata_types, ONLY: t_comin_var_metadata
 
  IMPLICIT NONE
 
  PRIVATE
 
  ! Public procedures, intention: called by host
  PUBLIC :: comin_request_list_iterator_begin
  PUBLIC :: comin_request_list_iterator_is_end
  PUBLIC :: comin_request_list_iterator_next
  PUBLIC :: comin_request_list_iterator_delete
  PUBLIC :: comin_var_request_get_descriptor
  PUBLIC :: comin_var_request_get_metadata
  PUBLIC :: comin_var_request_find
 
  ! Public procedures, intention: called by plugin
  PUBLIC :: comin_var_request_add
 
  ! Public procedures, intention: for internal use
  PUBLIC :: comin_var_request_find_c
 
  ! Direct forwards to C++ implementation.
  INTERFACE
 
    !> Create a new request list iterator, at the begin of the list.
    FUNCTION comin_request_list_iterator_begin() RESULT(ptr) BIND(C)
      IMPORT c_ptr
      TYPE(c_ptr) :: ptr ! New iterator.
    END FUNCTION comin_request_list_iterator_begin
 
    !> Compare the request list iterator with the end of the list.
    FUNCTION comin_request_list_iterator_is_end(it) RESULT(is_end) BIND(C)
      IMPORT c_ptr, c_bool
      TYPE(c_ptr), VALUE, INTENT(IN) :: it !< Iterator.
      LOGICAL(c_bool) :: is_end ! .TRUE. if at end of list.
    END FUNCTION comin_request_list_iterator_is_end
 
    !> Advance the iterator to the next element, returning the current one.
    FUNCTION comin_request_list_iterator_next(it) RESULT(item) BIND(C)
      IMPORT c_ptr
      TYPE(c_ptr), VALUE, INTENT(IN) :: it !< Iterator.
      TYPE(c_ptr) :: item ! Pointer to the current item.
    END FUNCTION comin_request_list_iterator_next
 
    !> Delete the request list iterator.
    SUBROUTINE comin_request_list_iterator_delete(it) BIND(C)
      IMPORT c_ptr
      TYPE(c_ptr), INTENT(INOUT) :: it !< Iterator.
    END SUBROUTINE comin_request_list_iterator_delete
 
  END INTERFACE
 
  ! Underlying functions to be wrapped.
  INTERFACE
 
    SUBROUTINE comin_var_request_add_c(var_descriptor, lmodexclusive) &
        & BIND(C, name="comin_var_request_add")
      IMPORT t_comin_var_descriptor_c, c_bool
      TYPE (t_comin_var_descriptor_c), VALUE, INTENT(IN)  :: var_descriptor
      LOGICAL(C_BOOL), VALUE,          INTENT(IN)  :: lmodexclusive
    END SUBROUTINE comin_var_request_add_c
 
    FUNCTION comin_var_request_get_metadata_c(request) RESULT(ptr) &
        & bind(c, name='comin_var_request_get_metadata')
      IMPORT c_ptr
      TYPE(c_ptr), VALUE, INTENT(IN) :: request
      TYPE(c_ptr) :: ptr
    END FUNCTION comin_var_request_get_metadata_c
 
    FUNCTION comin_var_request_get_descriptor_c(request) RESULT(ptr) &
        & bind(c, name='comin_var_request_get_descriptor')
      IMPORT c_ptr
      TYPE(c_ptr), VALUE, INTENT(IN) :: request
      TYPE(c_ptr) :: ptr
    END FUNCTION comin_var_request_get_descriptor_c
 
    !> Return the request item for the given C descriptor.
    FUNCTION comin_var_request_find_c(var_descriptor) RESULT(ptr) &
          & bind(c, name='comin_var_request_find')
      IMPORT c_ptr, t_comin_var_descriptor_c
      TYPE(t_comin_var_descriptor_c), INTENT(IN) :: var_descriptor !< C variable descriptor.
      TYPE(c_ptr) :: ptr ! Pointer to the request item or a disassociated pointer if no request exists.
    END FUNCTION comin_var_request_find_c
 
  END INTERFACE
 
CONTAINS
 
  !> By calling this subroutine inside the primary constructor, 3rd
  !! party plugins may request the creation of additional variables.
  !! @ingroup fortran_interface
  !!
  !!  Note: The lmodexclusive argument provides the information if this
  !!        variable is exclusive to the calling plugin.
  !!
  !!  Note: If a 3rd party plugin requests the creation of a variable
  !!        through this subroutine, it is still not guaranteed that
  !!        this variable is actually created! It might be skipped
  !!        due to inconsistencies, it could be a duplicate
  !!        etc. Therefore, 3rd party plugins still have to evaluate
  !!        the return code of `comin_var_request_add`.
  !!
  SUBROUTINE comin_var_request_add(var_descriptor, lmodexclusive)
    TYPE (t_comin_var_descriptor), INTENT(IN)  :: var_descriptor
    LOGICAL,                       INTENT(IN)  :: lmodexclusive
 
    CALL comin_var_request_add_c( &
        & t_comin_var_descriptor_c(var_descriptor), LOGICAL(lmodexclusive, c_bool))
  END SUBROUTINE comin_var_request_add
 
  !> Get the metadata associated with the given request.
  FUNCTION comin_var_request_get_metadata(req) RESULT(metadata)
    TYPE(c_ptr), VALUE, INTENT(IN) :: req !< Request pointer.
    TYPE(t_comin_var_metadata) :: metadata !< Associated metadata.
 
    metadata%comin_metadata_c = comin_var_request_get_metadata_c(req)
  END FUNCTION comin_var_request_get_metadata
 
  !> Get the descriptor associated with the given request.
  FUNCTION comin_var_request_get_descriptor(req) RESULT(descr)
    TYPE(c_ptr), VALUE, INTENT(IN) :: req !< Request pointer.
    TYPE(t_comin_var_descriptor) :: descr !< Variable descriptor.
 
    TYPE(t_comin_var_descriptor_c), POINTER :: descr_c
 
    CALL c_f_pointer(comin_var_request_get_descriptor_c(req), descr_c)
    descr = t_comin_var_descriptor(descr_c)
  END FUNCTION
 
  !> Find the request associated with the given descriptor.
  FUNCTION comin_var_request_find(var_descriptor) RESULT(req)
    TYPE(t_comin_var_descriptor), INTENT(IN) :: var_descriptor !< Variable descriptor.
    TYPE(c_ptr) :: req !< Pointer to the request or not associated.
 
    req = comin_var_request_find_c(t_comin_var_descriptor_c(var_descriptor))
  END FUNCTION comin_var_request_find
 
END MODULE comin_var_request