comin_plugin_info.F90

Go to the documentation of this file.

!> @file comin_plugin_info.F90
!! @brief Data shared between host and plugins.
!!
!! @authors 01/2026 :: ICON Community Interface  <comin@icon-model.org>
!
!  SPDX-License-Identifier: BSD-3-Clause
!
!  See LICENSES for license information.
!  Where software is supplied by third parties, it is indicated in the
!  headers of the routines.
!
MODULE comin_plugin_info
  use, INTRINSIC :: iso_c_binding, only: c_bool, c_ptr, c_int
 
  USE comin_c_utils, ONLY: convert_c_string
  USE comin_plugin_types, ONLY: t_comin_plugin_info
  USE comin_state, ONLY: comin_current_get_plugin_id
  USE comin_errhandler, ONLY: comin_plugin_finish
 
  IMPLICIT NONE
 
  PRIVATE
 
  PUBLIC :: comin_severity_debug
  PUBLIC :: comin_severity_info
  PUBLIC :: comin_severity_warning
  PUBLIC :: comin_severity_error
 
  PUBLIC :: comin_current_get_plugin_name
  PUBLIC :: comin_current_get_plugin_options
  PUBLIC :: comin_current_get_plugin_comm
  PUBLIC :: comin_current_get_plugin_errors_return
  PUBLIC :: comin_current_get_plugin_log_severity
 
  PUBLIC :: comin_current_get_plugin_info
 
  ENUM, BIND(C)
    ENUMERATOR :: &
      COMIN_SEVERITY_DEBUG = 0, & !< Show debug and more severe messages.
      comin_severity_info = 1, & !< Show info and more severe messages.
      comin_severity_warning = 2, & !< Show warning and more severe messages.
      comin_severity_error = 3 !< Only show error messages.
  END ENUM
 
  ! Helpers for Fortran
  INTERFACE
    TYPE(c_ptr) FUNCTION comin_current_get_plugin_name_c() &
        & BIND(C, name='comin_current_get_plugin_name')
      IMPORT c_ptr
    END FUNCTION comin_current_get_plugin_name_c
 
    TYPE(c_ptr) FUNCTION  comin_current_get_plugin_options_c() &
        & BIND(C, name='comin_current_get_plugin_options')
      IMPORT c_ptr
    END FUNCTION comin_current_get_plugin_options_c
 
    TYPE(c_ptr) FUNCTION  comin_current_get_plugin_comm_c() &
        & BIND(C, name='comin_current_get_plugin_comm')
      IMPORT c_ptr
    END FUNCTION comin_current_get_plugin_comm_c
 
    FUNCTION comin_current_get_plugin_errors_return_c() RESULT(errors_return) &
        & bind(c, name='comin_current_get_plugin_errors_return')
      IMPORT c_bool
      LOGICAL(c_bool) :: errors_return
    END FUNCTION comin_current_get_plugin_errors_return_c
 
    FUNCTION comin_current_get_plugin_log_severity_c() RESULT(severity) &
        & bind(c, name='comin_current_get_plugin_log_severity')
      IMPORT c_int
      INTEGER(c_int) :: severity
    END FUNCTION comin_current_get_plugin_log_severity_c
  END INTERFACE
 
CONTAINS
 
  !> Get the current plugin's name.
  FUNCTION comin_current_get_plugin_name() RESULT(res)
    CHARACTER(len=:), ALLOCATABLE :: res
    res = convert_c_string(comin_current_get_plugin_name_c())
  END FUNCTION comin_current_get_plugin_name
 
  !> Get the current plugin's options string.
  FUNCTION comin_current_get_plugin_options() RESULT(res)
    CHARACTER(len=:), ALLOCATABLE :: res
    res = convert_c_string(comin_current_get_plugin_options_c())
  END FUNCTION comin_current_get_plugin_options
 
  !> Get the current plugin's communicator name.
  FUNCTION comin_current_get_plugin_comm() RESULT(res)
    CHARACTER(len=:), ALLOCATABLE :: res
    res = convert_c_string(comin_current_get_plugin_comm_c())
  END FUNCTION comin_current_get_plugin_comm
 
  !> Get whether comin errors triggered in the current plugin do return back
  !! to the plugin or abort the program.
  !! @return `.TRUE.` if errors return to the plugin, `.FALSE.` otherwise.
  !! @ingroup fortran_interface
  FUNCTION comin_current_get_plugin_errors_return() RESULT(errors_return)
    LOGICAL :: errors_return
    errors_return = LOGICAL(comin_current_get_plugin_errors_return_c())
  END FUNCTION comin_current_get_plugin_errors_return
 
  !> Get the currently active log severity level.
  !! @return one of the `COMIN_SEVERITY` enum constants.
  !! @ingroup fortran_interface
  FUNCTION comin_current_get_plugin_log_severity() RESULT(severity)
    INTEGER :: severity
    severity = int(comin_current_get_plugin_log_severity_c())
  END FUNCTION comin_current_get_plugin_log_severity
 
  !> Returns the `t_comin_plugin_info` structure of the current plugin.
  !! It can for example be used to access the ID or the options string.
  !!
  !! @deprecated 0.5.0
  !!   Use the accessor functions @ref comin_current_get_plugin_name, etc.
  !!
  !! @ingroup fortran_interface
  SUBROUTINE comin_current_get_plugin_info(comin_current_plugin)
    TYPE(t_comin_plugin_info), INTENT(OUT) :: comin_current_plugin !< plugin info struct
 
    comin_current_plugin%id = comin_current_get_plugin_id()
    comin_current_plugin%name = convert_c_string(comin_current_get_plugin_name_c())
    comin_current_plugin%options = convert_c_string(comin_current_get_plugin_options_c())
    comin_current_plugin%comm = convert_c_string(comin_current_get_plugin_comm_c())
    comin_current_plugin%errors_return = comin_current_get_plugin_errors_return()
 
    SELECT CASE (comin_current_get_plugin_log_severity_c())
    CASE(comin_severity_debug)
      comin_current_plugin%log_debug = .true.
      comin_current_plugin%log_info = .true.
      comin_current_plugin%log_warning = .true.
    CASE(comin_severity_info)
      comin_current_plugin%log_debug = .false.
      comin_current_plugin%log_info = .true.
      comin_current_plugin%log_warning = .true.
    CASE(comin_severity_warning)
      comin_current_plugin%log_debug = .false.
      comin_current_plugin%log_info = .false.
      comin_current_plugin%log_warning = .true.
    CASE(comin_severity_error)
      comin_current_plugin%log_debug = .false.
      comin_current_plugin%log_info = .false.
      comin_current_plugin%log_warning = .false.
    CASE DEFAULT
      CALL comin_plugin_finish('comin_current_get_plugin_info', 'Internal error: unknown severity')
    END SELECT
 
  END SUBROUTINE comin_current_get_plugin_info
 
END MODULE comin_plugin_info